Downgrade kernel to 6.18LTS

Added themes, fixed kanshi, some emacs changes
2026-05-05 18:38:11 +02:00
parent fe1f941685
commit 028277a9ae
12 changed files with 224 additions and 75 deletions
@@ -0,0 +1,51 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let
+  cfg = config.dov.dynamic-theme;
+  schemes = "${pkgs.base16-schemes}/share/themes";
+
+  # Single source of truth for builtin themes
+  builtinThemes = {
+    gruvbox = {
+      dark = "${schemes}/gruvbox-dark-hard.yaml";
+      light = "${schemes}/gruvbox-light-hard.yaml";
+    };
+    catppuccin = {
+      dark = "${schemes}/catppuccin-mocha.yaml";
+      light = "${schemes}/catppuccin-latte.yaml";
+    };
+  };
+
+in {
+  options.dov.dynamic-theme = {
+    enable = mkEnableOption "dynamic theme switching";
+
+    themes = mkOption {
+      type = types.attrsOf (types.submodule {
+        options = {
+          dark = mkOption {
+            type = types.path;
+            description = "Path to dark variant base16 scheme";
+          };
+          light = mkOption {
+            type = types.path;
+            description = "Path to light variant base16 scheme";
+          };
+        };
+      });
+      default = builtinThemes;
+      description = "Available themes with dark and light variants";
+    };
+  };
+
+  config = mkIf cfg.enable {
+    # HM-level stylix config inherits from NixOS level
+    # Specialisations are handled by NixOS module
+    stylix = {
+      enable = true;
+      autoEnable = true;
+    };
+  };
+}